Just so you know, we don't know the file format for every file. If it's just a bunch of random characters, it's probably a .zip or .jar.

#REDPLUS SIGN BASE MODULE 1.4
#Created by Rixic (DemonSkripting)
#Public Skript (Release)
#http://hkzoffical.wix.com/demonskripts WEBSITE
#https://www.spigotmc.org/members/demonri.199402/ SPIGOT PROFILE
#©DemonSkripts All rights reserved

#Do not pubically distrubute this script or modifications of it without permission
#Do not sell this script or claim it as your own

function redplus_signLogic_SMITE(loc: location):
	set {_bool} to line 3 of block at {_loc}
	if {_bool} is not set:
		set line 3 of block at {_loc} to "FALSE"
	if {_bool} is "TRUE" or "T":
		strike lightning effect at {_loc}
	else:
		strike lightning at {_loc}
		
function redplus_signLogic_LAUNCHER(loc: location):
	set {_power} to line 3 of block at {_loc} parsed as a number
	if {_power} is not set:
		set line 3 of block at {_loc} to "1"
		set {_power} to 1
	set {_radius} to line 4 of block at {_loc} parsed as a number
	if {_radius} is not set:
		set line 4 of block at {_loc} to "1"
		set {_radius} to 1
	loop all entities in radius {_radius}, {_radius} and {_radius} around {_loc}:
		push loop-entity upwards at speed {_power}

		
function redplus_signLogic_POPFIREWORK(loc: location):
	#launch "BALL_LARGE" firework at {_loc} timed 0 coloured red
	launch firework at {_loc} timed 0
	
function redplus_signLogic_SPAWNMOB(loc: location):
	set {_entity} to line 3 of block at {_loc} parsed as entity type
	set {_amount} to line 4 of block at {_loc} parsed as a number
	if {_amount} is not set:
		set line 4 of block at {_loc} to "1"
		set {_amount} to 1
	spawn {_amount} of {_entity} at {_loc}
	
	
function redplus_signLogic_FCLOCK(loc: location):
	set {_interval} to line 3 of block at {_loc} parsed as a number
	if {_interval} is less than 2:
		set line 3 of block at {_loc} to "2"
		set {_interval} to 2
	if {_interval} is not set:
		set line 3 of block at {_loc} to "5"
		set {_interval} to 5
	set {_redstone} to redstone power being received at {_loc}
	while {_redstone} is more than 0:
		loop {_interval} times:
			wait 1 tick
			set {_redstone} to redstone power being received at {_loc}
			if {_redstone} is less than 1:
				stop
			if block at {_loc} is not a sign:
				stop
		set {_block} to block 1 behind block at {_loc}
		if {_block} is coal block:
			set line 1 of block at {_loc} to "&4No Inverted"
			set line 4 of block at {_loc} to "&4Support"
		set {_lever} to location 2 behind block at {_loc}
		redplus_outputSignTick({_block}, {_lever})
				
function redplus_signLogic_CLOCK(loc: location):
	set {_interval} to line 3 of block at {_loc} parsed as a number
	if {_interval} is less than 3:
		set line 3 of block at {_loc} to "3"
		set {_interval} to 3
	if {_interval} is not set:
		set line 3 of block at {_loc} to "5"
		set {_interval} to 5
	set {_redstone} to redstone power being received at {_loc}
	while {_redstone} is more than 0:
		loop {_interval} times:
			wait 1 tick
			set {_redstone} to redstone power being received at {_loc}
			if {_redstone} is less than 1:
				stop
			if block at {_loc} is not a sign:
				stop
		set {_block} to block 1 behind block at {_loc}
		set {_lever} to location 2 behind block at {_loc}
		redplus_outputSignRTick({_block}, {_lever})
		
function redplus_signLogic_DATAOUTPUT(loc: location):
	set {_interval} to line 3 of block at {_loc} parsed as a number
	if {_interval} is less than 3:
		set line 3 of block at {_loc} to "3"
		set {_interval} to 3
	if {_interval} is not set:
		set line 3 of block at {_loc} to "5"
		set {_interval} to 5
	set {_data} to line 4 of block at {_loc}
	set {_data::*} to {_data} split at ""
	set {_redstone} to redstone power being received at {_loc}
	set {_dataCount} to 0
	set {_maxData} to size of {_data::*}
	while {_redstone} is more than 0:
		loop {_interval} times:
			wait 1 tick
			set {_redstone} to redstone power being received at {_loc}
			if {_redstone} is less than 1:
				stop
		add 1 to {_dataCount}
		if {_data::%{_dataCount}%} is "1":
			set {_block} to block 1 behind block at {_loc}
			set {_lever} to location 2 behind block at {_loc}
			redplus_outputSignRTick({_block}, {_lever})
		if {_dataCount} is more than or equal to {_maxData}:
			set {_dataCount} to 0