Just so you know, we don't know the file format for every file. If it's just a bunch of random characters, it's probably a .zip or .jar.

# ##########################################################################
# Created by Creptor4
#
# Requires: SkBee (https://github.com/ShaneBeee/SkBee)
#           skript-placeholders (https://github.com/APickledWalrus/skript-placeholders)
#           PlaceholderAPI [plugin] (https://github.com/PlaceholderAPI/PlaceholderAPI)
#           ProtectionStones [plugin] (https://github.com/espidev/ProtectionStones)
#           JobsReborn [plugin] (https://www.spigotmc.org/resources/jobs-reborn.4216/)
#           Essentials [plugin] (https://essentialsx.net/)
#           Vault [plugin] (https://github.com/milkbowl/Vault)
# Language: es
#
# Version: 1.2
#
# ##########################################################################
variables:
    {color} = "&7"

# Function to load/refresh scoreboard
function update_scoreboard(p: player):
    set title of scoreboard of {_p} to "&4&l> %{color}%&lInfo &4&l<"
    set line 15 of scoreboard of {_p} to "%{color}%&m                                  "
    set line 14 of scoreboard of {_p} to "&6&l%placeholder "essentials_nickname" from {_p}%"
    set line 13 of scoreboard of {_p} to "Kills: &l%placeholder "statistic_player_kills" from {_p}%"
    set line 12 of scoreboard of {_p} to "Regiones: &6%placeholder "protectionstones_currentplayer_num_of_owned_regions" from {_p}%&f/&4%placeholder "changeoutput_equals _input:{protectionstones_currentplayer_global_region_limit}_matcher:-1_ifmatch:Ilimitado_else:{protectionstones_currentplayer_global_region_limit}" from {_p}%"
    set line 11 of scoreboard of {_p} to "Dinero: &2$%placeholder "vault_eco_balance_commas" from {_p}%"
    set line 10 of scoreboard of {_p} to ""
    set line 9 of scoreboard of {_p} to "Trabajos"
    set {_jobs::*} to (placeholder "jobsr_user_jobs" from {_p}) split at " &8|&r "
    set {_quest::*} to (placeholder "jobsr_user_quests" from {_p}) split at " &8|&r "
    loop {_jobs::*}:
        set {_c} to {_c} + 1
        set {_papi_job_quest} to first 11 characters of {_quest::%loop-index%}
        set {_papi_job_level} to placeholder "jobsr_user_jlevel_%loop-value%" from {_p}
        set line (9 - {_c}) of scoreboard of {_p} to "&9%loop-value% &7| &d&o%{_papi_job_quest}% &r&7| &6&l%{_papi_job_level}%"
    
    set line (9 - {_c} - 1) of scoreboard of {_p} to ""
    set line (9 - {_c} - 2) of scoreboard of {_p} to "servidor:"
    set line (9 - {_c} - 3) of scoreboard of {_p} to "&6&bmc.gallinaserver.cl"
    set line (9 - {_c} - 4) of scoreboard of {_p} to "%{color}%&m                                  "

# Load scoreboard on player
on login:
    update_scoreboard(player)

# Refresh scoreboard data
every 20 ticks:
    if {color} = "&f":
        set {color} to "&7"
    else:
        set {color} to "&f"
    
    loop all players:
        if scoreboard of loop-player is on:
            update_scoreboard(loop-player)
        
# Command 1
command /scoreboard-toggle:
    aliases: sc-toggle, marcador-toggle
    executable by: players
    description: "Alterna si se muestra/oculta el marcador."
    trigger:
        toggle scoreboard of player